**Linked Economy Ontology Cookbook**

Πίνακας περιεχομένων

[Πρόλογος 3](#_Toc435789596)

[ΧΑΑ - Χρηματιστήριο Αξίων Αθηνών (ASE - Athens Stock Exchange) 4](#_Toc435789597)

[Κλάσεις (Classes) 4](#_Toc435789598)

[FOAF 4](#_Toc435789599)

[Good Relations 4](#_Toc435789600)

[Organization 4](#_Toc435789601)

[Registered Organization 4](#_Toc435789602)

[Ιδιότητες Αντικειμένων (Object Properties) 4](#_Toc435789603)

[Linked Economy 4](#_Toc435789604)

[DBpedia 4](#_Toc435789605)

[Ιδιότητες Τύπου Δεδομένων (Datatype Properties) 4](#_Toc435789606)

[Linked Economy 4](#_Toc435789607)

[Ερωτήματα & Αποτελέσματα (SPARQL Queries) 4](#_Toc435789608)

[Στοιχεία Εισηγμένης Εταιρείας 4](#_Toc435789609)

[Συνδυασμός Πηγών 6](#_Toc435789610)

[Ερωτήματα & Αποτελέσματα (SPARQL Queries) 6](#_Toc435789611)

[Ανάδοχοι με συναλλαγές στη Διαύγεια, στο ΚΗΜΔΗΣ και στο ΕΣΠΑ 6](#_Toc435789612)

[Πλήθος συναλλαγών Αναδόχου στη Διαύγεια, ΚΗΜΔΗΣ και ΕΣΠΑ 6](#_Toc435789613)

[Εισηγμένες ταξινομημένες κατά το συνολικό ποσό Οριστικοποίησης Πληρωμών (Β.2.2) του έτους 2015 7](#_Toc435789614)

[Εισηγμένες ταξινομημένες κατά το συνολικό ποσό Πληρωμών ΕΣΠΑ 8](#_Toc435789615)

[Στοιχεία Πληρωμής και Αντικειμένου Εισηγμένης ως Ανάδοχος στο ΚΗΜΔΗΣ 10](#_Toc435789616)

# Πρόλογος

Σε αυτό το έγγραφο παρουσιάζεται η Οντολογία του LinkedEconomy η οποία προτείνεται για τη μοντελοποίηση της εκάστοτε πηγής. Παρουσιάζονται και περιγράφονται οι Κλάσεις, οι Ιδιότητες Αντικειμένων και οι Ιδιότητες Τύπου Δεδομένων των οντολογιών καθώς και παραδείγματα SPARQL ερωτημάτων με ένα δείγμα απαντήσεών τους. Κατά την αναπαράσταση των κλάσεων και των ιδιοτήτων χρησιμοποιούνται κάποια συγκεκριμένα namespaces και prefixes τα οποία παρουσιάζονται στον Πίνακα 1 μαζί με την οντολογία ή το λεξικό στο οποίο αντιστοιχούν.

|  |  |  |
| --- | --- | --- |
| Prefix | URI | Ontology / Vocabulary |
| rdf | http://www.w3.org/1999/02/22-rdf-syntax-ns# | RDF |
| rdfs | http://www.w3.org/2000/01/rdf-schema# | RDFS |
| xsd | http://www.w3.org/2001/XMLSchema# | XSD |
| gr | http://purl.org/goodrelations/v1# | Good Relations |
| pc | http://purl.org/procurement/public-contracts# | Public Contracts |
| foaf | http://xmlns.com/foaf/0.1/# | FOAF |
| org | http://www.w3.org/ns/org# | Organization |
| rov | http://www.w3.org/ns/regorg# | Registered Organization |
| dc | http://purl.org/dc/elements/1.1/ | Dublin Core |
| dcterms | http://purl.org/dc/terms/ | Dublin Core Terms |
| skos | http://www.w3.org/2004/02/skos/core# | SKOS |
| vCard | http://www.w3.org/2006/vcard/ns# | vCard |
| dbo | http://dbpedia.org/ontology/ | DBpedia |
| elod | http://linkedeconomy.org/ontology# | Linked Economy |
| elodGeo | http://linkedeconomy.org/geoOntology# | Linked Economy Geo |

Πίνακας 1: Τα prefixes και οι οντολογίες/λεξιλόγια στις οποίες ανήκουν

# ΧΑΑ - Χρηματιστήριο Αξίων Αθηνών (ASE - Athens Stock Exchange)

## Κλάσεις (Classes)

### FOAF

* foaf:Agent: Αυτή η κλάση αναπαριστά τις οντότητες οι οποίες συμμετέχουν σε δράσεις.
* foaf:Organization: Αυτή η κλάση αναπαριστά τους οργανισμούς. Είναι μία από τις τέσσερις κλάσεις οι οποίες χρησιμοποιούνται για τη μοντελοποίηση τους.

### Good Relations

* gr:BusinessEntity: Αυτή η κλάση αναπαριστά τους οργανισμούς. Είναι μία από τις τέσσερις κλάσεις οι οποίες χρησιμοποιούνται για τη μοντελοποίηση τους.

### Organization

* org:Organization: Αυτή η κλάση αναπαριστά τους οργανισμούς. Είναι μία από τις τέσσερις κλάσεις οι οποίες χρησιμοποιούνται για τη μοντελοποίηση τους.

### Registered Organization

* rov:RegisteredOrganization: Αυτή η κλάση αναπαριστά τους οργανισμούς. Είναι μία από τις τέσσερις κλάσεις οι οποίες χρησιμοποιούνται για τη μοντελοποίηση τους.

## Ιδιότητες Αντικειμένων (Object Properties)

### Linked Economy

* elod: relatesTo: Αυτή η ιδιότητα συσχετίζει μία επιχείρηση με κωδικό ISIN με μία άλλη από την βάση μας η οποία έχει ΑΦΜ.

### DBpedia

* dbo:subsidiary: Αυτή η ιδιότητα συσχετίζει μία επιχείρηση με τη θυγατρική της.

## Ιδιότητες Τύπου Δεδομένων (Datatype Properties)

### Linked Economy

* elod:isin: Ο κωδικός ISIN μίας επιχείρησης.
* elod:nameASE: Το όνομα μίας εισηγμένης επιχείρησης στο ΧΑΑ.
* elod:abbreviationASE: Το σύμβολο μίας εισηγμένης επιχείρησης στο ΧΑΑ.

## Ερωτήματα & Αποτελέσματα (SPARQL Queries)

### Στοιχεία Εισηγμένης Εταιρείας

PREFIX elod: <http://linkedeconomy.org/ontology#>

SELECT ?company ?isin ?nameEn ?abbrEn ?relatedUri

FROM <http://linkedeconomy.org/ASE>

WHERE {

?company elod:isin ?isin ;

elod:nameASE ?nameEn ;

elod:abbreviationASE ?abbrEn ;

elod:relatesTo ?relatedUri .

FILTER (LANG(?nameEn) = "en") .

FILTER (LANG(?abbrEn) = "en") .

}

LIMIT 5

Αποτελέσματα ερωτήματος

|  |  |  |  |  |
| --- | --- | --- | --- | --- |
| **Εταιρεία** | **ISIN** | **Όνομα** | **Συντο-μογραφία** | **Σχετιζόμενη Εταιρεία** |
| http://linkedeconomy.org/resource/Organization/BE0974271034 | "BE0974271034" | "Viohalco SA/NV"@en | "VIO"@en | http://linkedeconomy.org/resource/Person/094004569 |
| http://linkedeconomy.org/resource/Organization/CH0198251305 | "CH0198251305" | "Coca-Cola Hellenic Bottling Company AG"@en | "EEE"@en | http://linkedeconomy.org/resource/Organization/094277965 |
| http://linkedeconomy.org/resource/Organization/CY0104810110 | "CY0104810110" | "Bank Of Cyprus Public Company Limited"@en | "BOC"@en | http://linkedeconomy.org/resource/Organization/094014249 |
| http://linkedeconomy.org/resource/Organization/GRS001003003 | "GRS001003003" | "Attica Bank SA"@en | "TATT"@en | http://linkedeconomy.org/resource/Organization/094014170 |
| http://linkedeconomy.org/resource/Organization/GRS003003019 | "GRS003003019" | "National Bank of Greece SA"@en | "ETE"@en | http://linkedeconomy.org/resource/Organization/094014201 |

Για περισσότερα ερωτήματα συνδυασμένα με άλλες πηγές δεδομένων μπορείτε να ανατρέξετε στην ενότητα: «Συνδυασμός Πηγών».

# Συνδυασμός Πηγών

Η οντολογία προκύπτει από τη συνένωση των οντολογικών σχημάτων που περιγράφηκαν για τις παρακάτω πηγές: Διαύγεια, ΚΗΜΔΗΣ, ΕΣΠΑ και ΧΑΑ. Οι περιγραφή των κλάσεων και των ιδιοτήτων μπορούν να βρεθούν στις αντίστοιχες υποενότητες.

## Ερωτήματα & Αποτελέσματα (SPARQL Queries)

### Ανάδοχοι με συναλλαγές στη Διαύγεια, στο ΚΗΜΔΗΣ και στο ΕΣΠΑ

PREFIX elod: <http://linkedeconomy.org/ontology#>

PREFIX pc: <http://purl.org/procurement/public-contracts#>

SELECT DISTINCT ?seller

FROM <http://linkedeconomy.org/DiavgeiaII/2015>

FROM <http://linkedeconomy.org/EprocurementProper>

FROM <http://linkedeconomy.org/Subsidies>

WHERE {

#Diavgeia

?expAppr elod:hasExpenditureLine ?expLineExpAppr ;

rdf:type elod:ExpenseApprovalItem .

?expLineExpAppr elod:seller ?seller .

#KHMDHS

?cntr elod:seller ?seller ;

rdf:type pc:Contract .

#ESPA

?subsidy elod:beneficiary ?seller ;

rdf:type elod:Subsidy.

}

LIMIT 10

Αποτελέσματα ερωτήματος

|  |
| --- |
| **Ανάδοχος** |
| http://linkedeconomy.org/resource/Organization/082993120 |
| http://linkedeconomy.org/resource/Organization/094311705 |
| http://linkedeconomy.org/resource/Organization/102478909 |
| http://linkedeconomy.org/resource/Organization/032502798 |
| http://linkedeconomy.org/resource/Organization/101940406 |
| http://linkedeconomy.org/resource/Organization/082785679 |
| http://linkedeconomy.org/resource/Organization/082964412 |
| http://linkedeconomy.org/resource/Organization/800324752 |
| http://linkedeconomy.org/resource/Organization/094407125 |
| http://linkedeconomy.org/resource/Organization/090071277 |

### Πλήθος συναλλαγών Αναδόχου στη Διαύγεια, ΚΗΜΔΗΣ και ΕΣΠΑ

PREFIX gr: <http://purl.org/goodrelations/v1#>

PREFIX elod: <http://linkedeconomy.org/ontology#>

PREFIX pc: <http://purl.org/procurement/public-contracts#>

SELECT ?name (COUNT(DISTINCT(?expAppr)) AS ?expApprDiavgeia) (COUNT(DISTINCT(?cntr)) AS ?cntrKhmdhs) (COUNT(DISTINCT(?subsidy)) AS ?subsidyEspa)

FROM <http://linkedeconomy.org/DiavgeiaII/2015>

FROM <http://linkedeconomy.org/Organizations>

FROM <http://linkedeconomy.org/EprocurementProper>

FROM <http://linkedeconomy.org/Subsidies>

WHERE {

#Diavgeia

?expAppr elod:hasExpenditureLine ?expLineExpAppr ;

rdf:type elod:ExpenseApprovalItem .

?expLineExpAppr elod:seller <http://linkedeconomy.org/resource/Organization/800332672> .

#KHMDHS

?cntr elod:seller <http://linkedeconomy.org/resource/Organization/800332672> ;

rdf:type pc:Contract .

#ESPA

?subsidy elod:beneficiary <http://linkedeconomy.org/resource/Organization/800332672> ;

rdf:type elod:Subsidy.

#Name

<http://linkedeconomy.org/resource/Organization/800332672> gr:legalName ?name ;

gr:vatID ?vatID .

}

Αποτελέσματα ερωτήματος

|  |  |  |  |  |
| --- | --- | --- | --- | --- |
| **Ανάδοχος** | **ΑΦΜ** | **Εγκρίσεις Δαπανών** | **Συμβόλαια** | **Επιδοτήσεις** |
| FARGECO HELLAS ΣΥΛΛΟΓΗ ΕΠΕΞΕΡΓΑΣΙΑ ΑΠΟΡΡΙΜΜΑΤΩΝ ΕΤΑΙΡΕΙΑ ΠΕΡΙΟΡΙΣΜΕΝΗΣ ΕΥΘΥΝΗΣ ||FARGECO HELLAS ΕΠΕ | 800332672 | 6 | 13 | 1 |

### Εισηγμένες ταξινομημένες κατά το συνολικό ποσό Οριστικοποίησης Πληρωμών (Β.2.2) του έτους 2015

PREFIX elod: <http://linkedeconomy.org/ontology#>

PREFIX dcterms: <http://purl.org/dc/terms/>

SELECT ?company ?nameEn ?isin ?relatedUri (SUM(xsd:decimal(?amount)) AS ?totalAmountB22) (COUNT(DISTINCT ?payment) AS ?totalB22)

FROM <http://linkedeconomy.org/ASE>

FROM <http://linkedeconomy.org/DiavgeiaII/2015>

WHERE {

#ASE

?company elod:isin ?isin ;

elod:nameASE ?nameEn ;

elod:relatesTo ?relatedUri .

FILTER (LANG(?nameEn) = "en") .

#Diavgeia

?payment elod:hasExpenditureLine ?expenditureLine ;

dcterms:issued ?date ;

rdf:type elod:SpendingItem .

?expenditureLine elod:seller ?relatedUri ;

elod:amount ?ups .

?ups gr:hasCurrencyValue ?amount .

FILTER (?date >= "2015-01-01T00:00:00Z"^^xsd:dateTime) .

FILTER (?date < "2016-01-01T00:00:00Z"^^xsd:dateTime) .

}

GROUP BY ?company ?nameEn ?isin ?relatedUri

ORDER BY DESC (?totalAmountB22)

LIMIT 5

Αποτελέσματα ερωτήματος

|  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- |
| **Εταιρεία** | **Όνομα** | **Κωδικός ISIN** | **Σχετιζόμενη Εταιρεία** | **Συνολικό Ποσό** | **Πλήθος Πράξεων** |
| http://linkedeconomy.org/resource/Organization/GRS434003000 | Public Power Corporation S.A. | GRS434003000 | http://linkedeconomy.org/resource/Organization/090000045 | 219446050 | 8939 |
| http://linkedeconomy.org/resource/Organization/GRS323003004 | EFG Eurobank Ergasias SA | GRS323003004 | http://linkedeconomy.org/resource/Organization/094014250 | 99599986 | 866 |
| http://linkedeconomy.org/resource/Organization/GRS414003004 | Agricultural Bank Of Greece S.A. | GRS414003004 | http://linkedeconomy.org/resource/Organization/094014298 | 74716181 | 2647 |
| http://linkedeconomy.org/resource/Organization/GRS014003008 | Piraeus Bank SA | GRS014003008 | http://linkedeconomy.org/resource/Organization/094014298 | 74716181 | 2647 |
| http://linkedeconomy.org/resource/Organization/GRS359353000 | Athens Water Supply & Sewage Co. | GRS359353000 | http://linkedeconomy.org/resource/Organization/094079101 | 35090079 | 1819 |

### Εισηγμένες ταξινομημένες κατά το συνολικό ποσό Πληρωμών ΕΣΠΑ

PREFIX elod: <http://linkedeconomy.org/ontology#>

PREFIX pc: <http://purl.org/procurement/public-contracts#>

PREFIX gr: <http://purl.org/goodrelations/v1#>

SELECT ?company ?nameEn ?isin ?relatedUri (COUNT(?subsidy) AS ?subsidyCounter) (SUM(xsd:decimal(?biAmount)) AS ?biAmount) (SUM(xsd:decimal(?cntrAmount)) AS ?cntrAmount) (SUM(xsd:decimal(?siAmount)) AS ?siAmount)

FROM <http://linkedeconomy.org/ASE>

FROM <http://linkedeconomy.org/Subsidies>

WHERE {

#ASE

?company elod:isin ?isin ;

elod:nameASE ?nameEn ;

elod:relatesTo ?relatedUri .

FILTER (LANG(?nameEn) = "en") .

#ESPA

?subsidy elod:hasRelatedBudgetItem ?budgetItem ;

elod:hasRelatedContract ?contract ;

elod:hasRelatedSpendingItem ?spendingItem ;

elod:beneficiary ?relatedUri .

#budgetItem

?budgetItem elod:price ?biUps .

?biUps gr:hasCurrencyValue ?biAmount .

#contract

?contract pc:agreedPrice ?cntrUps .

?cntrUps gr:hasCurrencyValue ?cntrAmount.

#spendingItem

?spendingItem elod:amount ?siUps .

?siUps gr:hasCurrencyValue ?siAmount.

}

GROUP BY ?company ?nameEn ?isin ?relatedUri

ORDER BY DESC (?siAmount)

LIMIT 5

Αποτελέσματα ερωτήματος

|  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- |
| **Όνομα Πεδίου** | **Τιμές** | | | | |
| **Εταιρεία** | http://linkedeconomy.org/resource/Organization/GRS496003005 | http://linkedeconomy.org/resource/Organization/GRS271101008 | http://linkedeconomy.org/resource/Organization/GRS221103005 | http://linkedeconomy.org/resource/Organization/GRS469003024 | http://linkedeconomy.org/resource/Organization/GRS384003000 |
| **Όνομα** | "Terna Energy S.A."@en | "Elval - Hellenic Aluminium Industry S.A."@en | "Hellenic Cables S.A."@en | "Kri-Kri S.A."@en | "Kordellos CH. Bros S.A."@en |
| **Κωδικός ISIN** | "GRS496003005" | "GRS271101008" | "GRS221103005" | "GRS469003024" | "GRS384003000" |
| **Σχετιζόμε-νη Εταιρεία** | http://linkedeconomy.org/resource/Organization/094006030 | http://linkedeconomy.org/resource/Organization/094100416 | http://linkedeconomy.org/resource/Organization/094039428 | http://linkedeconomy.org/resource/Organization/094289571 | http://linkedeconomy.org/resource/Organization/094130887 |
| **Πλήθος Επιδοτή-σεων** | 9 | 4 | 2 | 6 | 1 |
| **Ποσό Προϋπολο-γισμού** | 34109134 | 6775009 | 5860473 | 3712138 | 2687320 |
| **Ποσό Συμβο-λαίου** | 34109134 | 6775009 | 5860473 | 3712138 | 2687320 |
| **Ποσό Πληρωμής** | 20102736 | 6565140 | 4917724 | 3569338 | 2687320 |

### Στοιχεία Πληρωμής και Αντικειμένου Εισηγμένης ως Ανάδοχος στο ΚΗΜΔΗΣ

PREFIX gr: <http://purl.org/goodrelations/v1#>

PREFIX elod: <http://linkedeconomy.org/ontology#>

PREFIX pc: <http://purl.org/procurement/public-contracts#>

SELECT ?company ?nameEn ?isin ?relatedUri ?payment ?signatureDate ?buyer ?buyerLegalName ?cpvEnglishSubject ?description ?amountOfThisGood ?unitOfMeasurement ?prodLabel (xsd:decimal(?amount) AS ?amount) ?vatPercentage (xsd:decimal((1+?vatPercentage/100)\*?amount) AS ?amountInclVat)

FROM <http://linkedeconomy.org/EprocurementProper>

FROM <http://publicspending.net/DiavgeiaI/CPV>

FROM <http://linkedeconomy.org/Organizations>

FROM <http://linkedeconomy.org/ASE>

WHERE {

#ASE

?company elod:isin ?isin ;

elod:nameASE ?nameEn ;

elod:relatesTo ?relatedUri .

FILTER (LANG(?nameEn) = "en") .

#KHMDHS

?payment elod:buyer ?buyer ;

pc:item ?offering ;

elod:signatureDate ?signatureDate .

#offering

?offering gr:includesObject ?tqn ;

gr:hasPriceSpecification ?ups ;

elod:seller ?relatedUri .

#tqn

?tqn gr:typeOfGood ?someItems ;

gr:amountOfThisGood ?amountOfThisGood ;

gr:hasUnitOfMeasurement ?unitOfMeasurement .

#ups

?ups elod:hasVat ?vat ;

gr:hasCurrencyValue ?amount .

#someItems

?someItems elod:productCategory ?cpv ;

gr:description ?description ;

elod:producedAt ?producedAt .

?buyer gr:legalName ?buyerLegalName .

?vat elod:vatPercentage ?vatPercentage .

?cpv elod:cpvEnglishSubject ?cpvEnglishSubject .

?producedAt skos:prefLabel ?prodLabel .

FILTER(LANGMATCHES(LANG(?prodLabel), "el")) .

FILTER NOT EXISTS {?payment elod:hasCorrectedDecision ?correctedDec } .

}

ORDER BY DESC (?amountInclVat)

LIMIT 1

Αποτελέσματα ερωτήματος

|  |  |
| --- | --- |
| **Όνομα Πεδίου** | **Τιμή** |
| **URI** | http://linkedeconomy.org/resource/Organization/GRS432003010 |
| **Όνομα** | "Intracom Constructions S.A.TECHN & Steel CONSTR."@en |
| **Κωδικός ISIN** | "GRS432003010" |
| **Σχετιζόμενο URI** | <http://linkedeconomy.org/resource/Organization/094207780> |
| **Πληρωμή** | <http://linkedeconomy.org/resource/Contract/13PAY001776162> |
| **Ημ/νια Υπογραφής** | 2013-12-11+03:00 |
| **Φορέας** | <http://linkedeconomy.org/resource/Organization/997612598> |
| **Όνομα Φορέα** | "ΠΕΡΙΦΕΡΕΙΑ ΚΕΝΤΡΙΚΗΣ ΜΑΚΕΔΟΝΙΑΣ"@el |
| **Περιγραφή CPV** | "Road construction works" |
| **Περιγραφή Πληρωμής** | Κατασκευή οδικού τμήματος Ποτίδαια- Κασσανδρεία του οδικού κυκλώματος Κασσάνδρας Ν. Χαλκιδικής (Υπογράφων σύμβασης Μπέκας Παύλος Δ/ντης ΔΕΚΕ ΠΚΜ) |
| **Ποσότητα** | 1.0 |
| **Μονάδα Μέτρησης** | Service |
| **Χώρα Προέλευσης** | "Ελλάδα"@el |
| **Ποσό (χωρίς ΦΠΑ)** | 41920968 |
| **ΦΠΑ** | 23.0 |
| **Ποσό (με ΦΠΑ)** | 51562791.43 |